// Dartmouth CS 2, Winter 2009, Chris Bailey-Kellogg
// Notes 21 | Sketch 1

import JMyron.*;

JMyron video;  // Video capture

void setup()
{
  size(640,480);
  smooth();
  
  video = new JMyron();
  video.start(width,height);
  video.minDensity(1000);      // decent-sized globs
  video.trackColor(0,0,0,200); // fairly dark globs
}

void draw()
{
  video.update();
  
  // Camera image
  loadPixels();
  video.imageCopy(pixels);
  updatePixels();
  
  // Outlines of globs
  stroke(0,255,0); noFill();
  // an array (over globs) of arrays (over edge points) of 2 elements (0=x, 1=y)
  int[][][] edgePointSets = video.globEdgePoints(30);
  for (int eps=0; eps<edgePointSets.length; eps++) {
    // an array (over edge points) of 2 elements (0=x, 1=y)
    int[][] edgePoints = edgePointSets[eps];
    if (edgePoints != null) { // following one of the examples
      beginShape();
      for (int p=0; p<edgePoints.length; p++) {
        // an array of 0=x, 1=y
        int[] edgePoint = edgePoints[p];
        vertex(edgePoint[0], edgePoint[1]);
      }
      endShape(CLOSE);
    }
  }
}