// Dartmouth CS 2, Winter 2009, Chris Bailey-Kellogg
// Notes 9 | Sketch 7

int num=100;         // how many points
int sz=10;           // how big an aerosol
boolean rand=false;  // all points random colors?

void setup()
{
  size(400,400);
  smooth();
  background(0);
  noFill();
  stroke(255);
}

void draw()
{
  if (mousePressed) {
    for (int i=0; i<num; i++) {
      // Generate point
      float x = mouseX+random(-sz,sz);
      float y = mouseY+random(-sz,sz);
      // Is it in the circle
      if (dist(x,y,mouseX,mouseY) < sz) {
        if (rand) stroke(random(255),random(255),random(255));
        point(x, y);
      }
    }
  }
}

void keyPressed()
{
  if (key=='c') {        // random color
    rand = false;
    stroke(random(255),random(255),random(255));
  }
  else if (key=='r') {   // random colors
    rand = true;
  }
  else if (key=='Z') {   // bigger size
    if (sz<100) sz++;
  }
  else if (key=='z') {
    if (sz>0) sz--;
  }
  else if (key=='P') {   // more points
    if (num<1000) num+=10;
  }
  else if (key=='p') {
    if (num>10) num-=10;
  }
}